+--------------------------------------------------------------------+
| |
| MULTIPLE_DOSE EXAMPLE |
| |
+--------------------------------------------------------------------+
This example is based on work described in Fattinger K. et al.,
Netilmicin in the neonate - population pharmacokinetic analysis and
dosing recommendations, Clinical Pharmacology and Therapeutics, 1991,
Jul, V50; N1:55-65. It illustrates a data file with multiple doses of
different kinds.
A FORTRAN format statement is needed to describe the data file because
each data record spans two FORTRAN records and also because blanks are
sometimes used for null data items.
Explanation of data items:
TIME hours
KG bodyweight(kg)
LENG length(cm)
SEX 0 for female and 1 for male
GAGE gestational age at birth
AGE actual age (in days)
AGE1 age at start of therapy
IMIV im or iv dose (1.0 is iv and 0.0 is im)
CREA creatinine value
TAD time after last dose (h)
All doses are given as zero order infusions. The RATE data item is
-2, indicating that duration D1 is modeled in the $PK block. There
are two types of doses: IV (intravenous) and IM (intramuscular). The
duration of IV doses is 2 minutes. The duration of IM doses is
unknown and is given by theta(7).
The Estimation Step produces a Model Specification File, which may be
used in in a later run; (See $msfi, model specification file).
$PROBLEM NETILMICIN
$INPUT ID MDV TIME AMT RATE CP=DV KG LENG SEX
GAGE AGE AGE1 IMIV CREA TAD
$DATA data (6F7.0/7X,9F7.0)
$SUBROUTINE ADVAN3,TRANS4
$PK
TVCL1=THETA(1)*KG
GAGEN=GAGE/39.0
PAN=(AGE+1.0)/7.0
IF(GAGE.LT.39.0) THEN
TVCL=TVCL1*(GAGEN**THETA(3))*(PAN**THETA(2))
ELSE
TVCL=TVCL1*(PAN**THETA(2))
ENDIF
CL=TVCL*EXP(ETA(1))
TVV1=THETA(4)*KG
V1=TVV1*EXP(ETA(2))
Q=THETA(5)
V2=THETA(6)*KG
S1=V1
IF(IMIV.GE.1.0) THEN
D1=.0333333 ; 2./60.
ELSE
D1=THETA(7)
ENDIF
$ERROR
Y=F*(1+EPS(1))
$THETA (0,0.07) (0,0.1) (0,1.1) (0,0.4) (0,0.07) (0,0.8) (0,.033)
$OMEGA 0.02 0.02
$SIGMA 0.02
$ESTIMATION PRINT=5 MSFO=msfo1
$COVARIANCE
$TABLE MDV ID KG LENG SEX GAGE AGE TAD BY MDV ID NOPRINT FILE=NTABLE.DAT
$SCATTER PRED VS CP UNIT
Data for one subject follow. This subject received both IM and IV
doses.
6.0 1.0 0.0 13.0 -2.0
6.0 2.590 47.0 0.0 36.0 0.0 0.0 1.0 56.0 0.0
6.0 1.0 24.0 10.4 -2.0
6.0 2.590 47.0 0.0 36.0 1.0 0.0 1.0 56.0 0.0
6.0 0.0 26.0 0.0 0.0 6.95
6.0 2.590 47.0 0.0 36.0 1.0 0.0 1.0 56.0 2.0 0.0
6.0 0.0 32.0 0.0 0.0 3.45
6.0 2.590 47.0 0.0 36.0 1.0 0.0 1.0 56.0 8.0 0.0
6.0 0.0 40.0 0.0 0.0 1.8
6.0 2.590 47.0 0.0 36.0 2.0 0.0 1.0 56.0 16.0 0.0
6.0 1.0 48.0 10.4 -2.0
6.0 2.590 47.0 0.0 36.0 2.0 0.0 0.0 56.0 0.0
6.0 1.0 72.0 10.4 -2.0
6.0 2.590 47.0 0.0 36.0 3.0 0.0 0.0 56.0 0.0
6.0 1.0 96.0 10.4 -2.0
6.0 2.590 47.0 0.0 36.0 4.0 0.0 0.0 56.0 0.0
6.0 1.0 120.0 10.4 -2.0
6.0 2.590 47.0 0.0 36.0 5.0 0.0 0.0 56.0 0.0
6.0 0.0 122.0 0.0 0.0 5.9
6.0 2.590 47.0 0.0 36.0 5.0 0.0 0.0 56.0 2.0 0.0
6.0 0.0 128.0 0.0 0.0 2.1
6.0 2.590 47.0 0.0 36.0 5.0 0.0 0.0 56.0 8.0 0.0
6.0 0.0 136.0 0.0 0.0 0.75
6.0 2.590 47.0 0.0 36.0 6.0 0.0 0.0 56.0 16.0 0.0
(See duration, $data).
REFERENCES: Guide VI Section V.D
REFERENCES: Guide V Section 6.8, 6.10
Go to main index.
Created by nmhelp2html v. 1.0 written by Niclas Jonsson (Modified by AJB 5/2006,11/2007,10/2012)