+--------------------------------------------------------------------+
 |                                                                    |
 |                          BAYES EXAMPLE 9                           |
 |                                                                    |
 +--------------------------------------------------------------------+

 This is example9.ctl from the NONMEM 7 distribution medium.  It, along
 with the data file, can be found in the examples directory.

 ;Model Desc: Two compartment Model, Using ADVAN3, TRANS4
 ;Project Name: nm7examples
 ;Project ID: NO PROJECT DESCRIPTION

 $PROB RUN# Example 9 (from samp5l)
 $INPUT C SET ID JID TIME  DV=CONC AMT=DOSE RATE EVID MDV CMT
        CLX V1X QX V2X SDIX SDSX
 $DATA example9.csv IGNORE=C

 $SUBROUTINES ADVAN3 TRANS4 OTHER=aneal.f90

 $PK
 MU_1=THETA(1)
 MU_2=THETA(2)
 MU_3=THETA(3)
 MU_4=THETA(4)
 CL=DEXP(MU_1+ETA(1))
 V1=DEXP(MU_2+ETA(2))
 Q=DEXP(MU_3+ETA(3))
 V2=DEXP(MU_4+ETA(4))
 S1=V1

 $ERROR
 Y = F + F*EPS(1)

 ; Initial values of THETA
 $THETA
 (0.001, 2.0) ;[LN(CL)]
 (0.001, 2.0) ;[LN(V1)]
 (0.001, 2.0) ;[LN(Q)]
 (0.001, 2.0) ;[LN(V2)]
 ;INITIAL values of OMEGA
 $OMEGA BLOCK(4)
 0.05   ;[P]
 0.01  ;[F]
 0.05   ;[P]
 0.01  ;[F]
 0.01  ;[F]
 0.05   ;[P]
 0.01  ;[F]
 0.01  ;[F]
 0.01  ;[F]
 0.05   ;[P]
 ;Initial value of SIGMA
 $SIGMA
 (0.6 )   ;[P]

 $EST METHOD=SAEM INTERACTION FILE=example9.ext NBURN=5000
      NITER=500 PRINT=10 NOABORT SIGL=6 CTYPE=3 CINTERVAL=100
      CITER=10 CALPHA=0.05

REFERENCES: Guide Introduction_7

  
Go to main index.
  

    Created by nmhelp2html v. 1.0 written by Niclas Jonsson (Modified by AJB 5/2006,11/2007,10/2012)